Wikizdroje:SPARQL Query Service/dotazy/příklady
Tato stránka obsahuje příklady pro SPARQL dotazovací službu (SPARQL query service), které se týkají Wikizdrojů.
Obecně editovat
Počet všech entit z Wikizdrojů propojených na Wikidata editovat
# Počet všech entit z Wikizdrojů propojených na Wikidata.
SELECT (COUNT(?item) AS ?count) WHERE {
?sitelink schema:isPartOf <https://cs.wikisource.org/> ;
schema:about ?item .
}
Instance na Wikidatech s propojením na Wikizdroje a počet editovat
# Instance na Wikidatech s propojením na Wikizdroje a počet.
SELECT ?instance ?instanceLabel ?count WHERE {
{
SELECT ?instance (COUNT(?item) AS ?count) WHERE {
?item wdt:P31 ?instance.
?sitelink schema:isPartOf <https://cs.wikisource.org/> ;
schema:about ?item .
} GROUP BY ?instance
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs". }
} ORDER BY DESC(?count)
Autoři editovat
Počet lidí s článkem na Wikizdrojích editovat
# Počet lidí s článkem na Wikizdrojích.
SELECT ?count WHERE {
{
SELECT (COUNT(?item) AS ?count) WHERE {
?item wdt:P31 wd:Q5.
?sitelink schema:isPartOf <https://cs.wikisource.org/> ;
schema:about ?item .
}
}
}
Lidé s článkem na Wikizdrojích, ale bez externího identifikátoru na Wikidatech editovat
# Lidé s článkem na Wikizdrojích, ale bez externího identifikátoru na Wikidatech.
SELECT ?item ?sitelink ?itemLabel WHERE {
?sitelink schema:isPartOf <https://cs.wikisource.org/> ;
schema:about ?item .
?item wdt:P31 wd:Q5 ;
wikibase:identifiers 0 .
SERVICE wikibase:label {bd:serviceParam wikibase:language "cs"}
} ORDER BY ?itemLabel
Seznam 100 nejvíce zastoupených příjmení na Wikizdrojích editovat
# Seznam 100 nejvíce zastoupených příjmení na Wikizdrojích.
#defaultView:BubbleChart
SELECT ?surname ?surnameLabel ?count WHERE {
{
SELECT ?surname (COUNT(?person) AS ?count) WHERE {
?person wdt:P31 wd:Q5.
?article schema:about ?person;
schema:isPartOf <https://cs.wikisource.org/> .
?person wdt:P734 ?surname.
}
GROUP BY ?surname
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs". }
} ORDER BY DESC(?count) LIMIT 100
Seznam 100 nejvíce zastoupených příjmení na Wikizdrojích s neuvedenými editovat
# Seznam 100 nejvíce zastoupených příjmení na Wikizdrojích s neuvedenými.
#defaultView:BubbleChart
SELECT ?surname ?surnameLabel ?count WHERE {
{
SELECT ?surname (COUNT(?person) AS ?count) WHERE {
?person wdt:P31 wd:Q5.
?article schema:about ?person;
schema:isPartOf <https://cs.wikisource.org/> .
OPTIONAL { ?person wdt:P734 ?surnameOpt. }
BIND (COALESCE(?surnameOpt, wd:Q24238356 ) AS ?surname)
} GROUP BY ?surname
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs". }
} ORDER BY DESC(?count) LIMIT 100
Díla editovat
Počet vydání s článkem na Wikizdrojích editovat
# Počet vydání s článkem na Wikizdrojích.
SELECT ?count WHERE {
{
SELECT (COUNT(?item) AS ?count) WHERE {
?item wdt:P31 wd:Q3331189.
?sitelink schema:isPartOf <https://cs.wikisource.org/> ;
schema:about ?item .
}
}
}
Seznam vydání, které mají heslo na Wikizdrojích editovat
# Seznam vydání, které mají heslo na Wikizdrojích.
SELECT ?item ?article WHERE {
?article schema:about ?item.
?article schema:isPartOf <https://cs.wikisource.org/>.
?item wdt:P31 wd:Q3331189.
}
Kontrolní dotazy editovat
Seznam Wikidat zaznamů, které odkazují na Wikizdroje ve jmenném prostoru Stránka editovat
Výsledek má být 0 záznamů, všechny existující patří smazat.
# Seznam Wikidat zaznamů, které odkazují na Wikizdroje ve jmenném prostoru Stránka.
SELECT ?item ?article WHERE {
?article schema:about ?item.
?article schema:isPartOf <https://cs.wikisource.org/>.
FILTER (STRSTARTS(str(?article), "https://cs.wikisource.org/wiki/Str%C3%A1nka:"))
}
Seznam vydání, které mají heslo na Wikizdrojích a nemají vyplněný jazyk editovat
Výsledek má být 0 záznamů, do všech existujících patří přidat jazyk.
# Seznam vydání, které mají heslo na Wikizdrojích a nemají vyplněný jazyk.
SELECT ?item ?article WHERE {
?article schema:about ?item.
?article schema:isPartOf <https://cs.wikisource.org/>.
?item wdt:P31 wd:Q3331189.
OPTIONAL{ ?item wdt:P407 ?lang }
FILTER (!BOUND(?lang))
}
Seznam vydání, které mají heslo na Wikizdrojích a nemají vyplněný rok vydání editovat
Výsledek má být 0 záznamů, do všech existujících patří přidat rok vydání.
# Seznam vydání, které mají heslo na Wikizdrojích a nemají vyplněný rok vydání
SELECT ?item ?article WHERE {
?article schema:about ?item.
?article schema:isPartOf <https://cs.wikisource.org/>.
?item wdt:P31 wd:Q3331189.
OPTIONAL{ ?item wdt:P577 ?publication_date }
FILTER (!BOUND(?publication_date))
}
Seznam autorů na Wikizdrojích, kteří nemají vyplněný jazyk, který ovládají editovat
# Seznam autorů na Wikizdrojích, kteří nemají vyplněný jazyk, který ovládají.
SELECT ?people ?peopleLabel ?article WHERE {
?people wdt:P31 wd:Q5 .
OPTIONAL {?people wdt:P1412 ?d} .
?article schema:about ?people .
?article schema:inLanguage "cs" .
FILTER (SUBSTR(str(?article), 1, 26) = "https://cs.wikisource.org/")
FILTER (!BOUND(?d))
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs" }
}
Seznam autorů na Wikizdrojích, kteří nemají vyplněné příjmení editovat
# Seznam autorů na Wikizdrojích, kteří nemají vyplněné příjmení.
SELECT ?person ?personLabel WHERE {
?person wdt:P31 wd:Q5.
?article schema:about ?person;
schema:isPartOf <https://cs.wikisource.org/> .
FILTER NOT EXISTS {?person wdt:P734 ?surname} .
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs". }
}
Otttův slovník naučný editovat
Seznam autorů článků Ottova slovníku naučného podle počtu článků editovat
# Seznam autorů článků Ottova slovníku naučného podle počtu článků
SELECT (COUNT(?aut) AS ?count) ?aut ?autLabel WHERE {
?work wdt:P31 wd:Q13433827;
wdt:P50 ?aut;
wdt:P1433 wd:Q2041543.
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs". }
}
GROUP BY ?aut ?autLabel
ORDER BY DESC(?count)
LIMIT 200
Seznam článků Ottova slovníku naučného, které nemají vyplněnu vlastnost hlavní téma díla editovat
# Seznam článků Ottova slovníku naučného, které nemají vyplněnu vlastnost hlavní téma díla
SELECT ?work ?workLabel
WHERE
{
?work wdt:P31 wd:Q13433827;
wdt:P1433 wd:Q2041543.
MINUS { ?work wdt:P921 ?mt}
SERVICE wikibase:label { bd:serviceParam wikibase:language "cs". }
}